L'objet IXMLDOMParseError retourne les informations détaillées à propos de la dernière erreur d'analyse en incluant le numéro, la ligne, la colonne de l'erreur.

Objet_Erreur = Objet_Document.parseError
Les Propriétés
Propriété
Description
Valeur = Objet_ParseError.errorCode
contient le code de l'erreur da la dernière erreur d'analyse, en lecture seule.
Valeur = Objet_ParseError.filepos
contient la position du fichier absolue où l'erreur s'est produite, en lecture seule.
Valeur = Objet_ParseError.line
spécifie le numéro de la ligne contenant l'erreur, en lecture seule.
Valeur = Objet_ParseError.linepos
contient la position du caractère à l'intérieur de la ligne où l'erreur s'est produite, en lecture seule.
Chaîne = Objet_ParseError.reason
fournit une explication à propos de l'erreur, en lecture seule.
Chaîne = Objet_ParseError.srcText
retourne le texte complet de la ligne contenant l'erreur, en lecture seule.
Chaîne = Objet_ParseError.url
contient l'adresse URL du document XML contenant la dernière erreur, en lecture seule.
Exemple [voir] 
<%
  Dim Objet_Document, Objet_Processeur
  Dim Objet_Style, Objet_Modele
  Dim fichier_xml, fichier_xsl
  Dim Objet_ErrXML, Objet_ErrXSL, Objet_Erreur

  Set Objet_Document = Server.CreateObject("MSXML2.DOMDocument")
  Set Objet_Style = Server.CreateObject("MSXML2.FreeThreadedDOMDocument")
  Set Objet_Modele = Server.CreateObject("MSXML2.XSLTemplate")

  Objet_Document.async = False
  Objet_Style.async = False
  fichier_xml = Server.MapPath("logithseque.xml")
  fichier_xsl = Server.MapPath("logithesque.xsl")
  Objet_Document.Load fichier_xml
  Objet_Style.Load fichier_xsl

  Set Objet_ErrXML = Objet_Document.parseError
  Set Objet_ErrXSL = Objet_Style.parseError

  Sub fonction_erreur(Objet_Erreur)
    Response.Write "<h3>Le chargement a échoué.</h3>" _
                           & "<br><b>Une erreur d'analyse s'est produite.</b>" _
                          & "<br><u>Code :</u> " & Objet_Erreur.errorCode _
                          & "<br><u>Raison :</u> " & Objet_Erreur.reason _
                          & "<br><u>Texte :</u> " & Objet_Erreur.srcText _
                          & "<br><u>URL :</u> " & Objet_Erreur.url _
                          & "<br><u>Position :</u> " & Objet_Erreur.filePos _
                          & "<br><u>Ligne :</u> " & Objet_Erreur.line _
                          & "<br><u>Colonne :</u> " & Objet_Erreur.linePos
  End Sub

  If Objet_ErrXML.errorCode <> 0 OR Objet_ErrXSL.errorCode <> 0 Then
    If Objet_ErrXML.errorCode <> 0 Then
      fonction_erreur(Objet_ErrXML)
    End If
    If Objet_ErrXSL.errorCode <> 0 Then
      fonction_erreur(Objet_ErrXSL)
    End If
  Else
    Set Objet_Modele.stylesheet = Objet_Style
    Set Objet_Processeur = Objet_Modele.createProcessor()
    Objet_Processeur.input = Objet_Document
    Objet_Processeur.addParameter "num", 6
    Objet_Processeur.Transform
    Response.Write Objet_Processeur.output
  End If

  Set Objet_Document = Nothing
  Set Objet_Style = Nothing
  Set Objet_Modele = Nothing
  Set Objet_Processeur = Nothing
%>