L'objet RegExp permet de créer des expressions régulières.

Set objet = New RegExp
Les propriétés
Propriété
Description
objet.Global [=True|False]
définit ou retourne une valeur logique indiquant si toutes les occurrences d'une chaîne de caractères de recherche ou seulement la première chaîne doivent satisfaire aux critères.
objet.IgnoreCase [=True|False]
définit ou retourne une valeur logique indiquant si les critères de recherche doivent distinguer la casse des caractères.
objet.Pattern [="chaîne"]
définit ou retourne les critères de recherche de l'expression régulière.
Les méthodes
Méthode
Description
objet.Execute(chaîne)
exécute une recherche de la chaîne de caractères passée en argument dans une expression régulière.
objet.Replace(recherche, remplace)
remplace la première chaîne de caractères recherche trouvée dans l'expression régulière par la seconde remplace.
objet.Test(Chaîne)
teste la présence d'une chaîne de caractères passée en argument dans une expression régulière.
Exemple : [voir] 
<html>
  <body>
    <%
      Dim texte, resultat

      Function recherche(modele, chaine)
        Dim objet
        Dim correspondance
        Dim collection

        Set objet = New RegExp
        objet.Pattern = modele
        objet.IgnoreCase = True
        objet.Global = True
        Set collection = objet.Execute(chaine)

        For Each correspondance in collection
          resultat = resultat & "<tr><td>" & correspondance.FirstIndex _
                      & "</td><td>" & correspondance.Value & "</td></tr>"
        Next
        recherche = resultat
      End Function

      texte = "Le chercheur d'opale a trouvé une belle pierre dans " _
               & "une galerie sinistre, pour le plus grand bonheur de " _
               & "la population occidentale qui pourtant se désolerait " _
               & " de travailler dans de telles conditions inhumaines."

      resultat = recherche(_
                     "\b[a-zA-Zàâäéèêëïîôöùûç]*le[a-zA-Zàâäéèêëïîôöùûç]*\b",_
                                                                                       texte)
      Response.Write "<h3>Liste des mots contenant la " _
                          & "chaîne de caractères <I>le</I></h3>" _
                          & "<h4>Texte</h4><p>" & texte & "</p>" _
                          & "<table border='1' cellpadding='3'>" _
                          & "<tr><th>Position</th><th>Mot</th></tr>" _
                          & resultat & "</table>"
    %>
  </body>
</html>